blRet = ConvertReportToPDF("rptPOrders", vbNullString, "H:\Purchase_Orders\" & "PO# " & Me.PONumber & "_" & Me.MarkFor & "_" & Me.VendorsID.Column(1) & ".pdf", False, True, 150, "", "", 0, 0, 0)

Declare Function apiWNetGetConnection Lib "mpr.dll" Alias "WNetGetConnectionA" _
  (ByVal strLocalName As String, ByVal strRemoteName As String, _
   ByRef rlngRemoteNameLen As Long) As Long

Public Function GetUNC(ByVal strPath As String) As String
'Note, this function will only return the UNC for network drives.
'Non-net drives and errors get the original value returned to them
On Error GoTo Err_GetUNC
    Const lngcBuffer As Long = 257
    Dim strUNCPath As String
    Dim strDrive As String
    If left(strPath, 2) Like "[a-z, A-Z]:" Then
        strDrive = left(strPath, 2)
        strUNCPath = strUNCPath & Space(lngcBuffer)
        'The function will automatically fill the strUNCPath unless there
        'is an error (return<>0), fill strPath if error
        If apiWNetGetConnection(strDrive, strUNCPath, lngcBuffer) = 0 Then
            strUNCPath = TrimNull(strUNCPath) & Mid(strPath, 3)
        Else
            strUNCPath = strPath
        End If
    End If
    If Len(Trim(strUNCPath)) = 0 Then strUNCPath = strPath
    GetUNC = strUNCPath
Exit_GetUNC:
    Exit Function
Err_GetUNC:
    MsgBox "Error " & Err.Number & " " & Err.Description
    Resume Exit_GetUNC
End Function

Public Function TrimNull(ByVal strNullTermString As String) As String
'This function is used to return a string from a DLL null-terminated string
On Error GoTo Err_TrimNull
    Dim lngNullPos As Long
    lngNullPos = InStr(strNullTermString, vbNullChar)
    If lngNullPos > 0 Then
        TrimNull = left(strNullTermString, lngNullPos - 1)
    Else
        TrimNull = strNullTermString
    End If
Exit_TrimNull:
    Exit Function
Err_TrimNull:
    MsgBox "Error " & Err.Number & " " & Err.Description
    Resume Exit_TrimNull
End Function