Public Sub SendSMTPEmail(strSubject As String, _
       strBodyText As String, _
       strRecipient As String, _
       Optional varCC As Variant, _
       Optional varBCC As Variant, _
       Optional varFrom As Variant, _
       Optional colAttachmentPath As VBA.Collection)

Dim objMessage As Object
Dim objConfig As Object
Dim objFields As Object
Dim intIndex As Integer

Const cdoSendUsingPickup = 1 'Send message using the local SMTP service pickup directory.
Const cdoSendUsingPort = 2 'Send the message using the network (SMTP over the network).

Const cdoAnonymous = 0 'Do not authenticate
Const cdoBasic = 1 'basic (clear-text) authentication
Const cdoNTLM = 2 'NTLM

'Delivery Status Notifications
Const cdoDSNDefault = 0 'None
Const cdoDSNNever = 1 'None
Const cdoDSNFailure = 2 'Failure
Const cdoDSNSuccess = 4 'Success
Const cdoDSNDelay = 8 'Delay
Const cdoDSNSuccessFailOrDelay = 14 'Success, failure or delay

Set objMessage = CreateObject("CDO.Message")
Set objConfig = CreateObject("CDO.Configuration")

'==This section provides the configuration information for the remote SMTP server.

Set objFields = objConfig.Fields
With objFields
  .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = cdoSendUsingPort

  'Name or IP of Remote SMTP Server
  .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.server-name.com" '*** ADD SMTP SERVER NAME HERE

  'Type of authentication, NONE, Basic (Base64 encoded), NTLM
  .Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic
  
  'Your UserID on the SMTP server
  .Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "account-name" '*** ADD ACCOUNT NAME HERE
  
  'Your password on the SMTP server
  .Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "account-password" '*** ADD ACCOUNT PASSWORD HERE
  
  'Server port (typically 25)
  .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
  
  'Use SSL for the connection (False or True)
  .Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False
  
  'Connection Timeout in seconds (the maximum time CDO will try to establish a connection to the SMTP server)
  .Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
  
  .Update
End With

With objMessage
  Set .configuration = objConfig
  
  .Subject = strSubject
  .From = IIf(IsMissing(varFrom), "default@email-address.com", varFrom) '*** ADD A DEFAULT EMAIL ADDRESS HERE
  .To = strRecipient
  .TextBody = strBodyText
  
  If Not (colAttachmentPath Is Nothing) Then
   For intIndex = 1 To colAttachmentPath.Count
    .AddAttachment colAttachmentPath(intIndex)
   Next intIndex
  End If
  
  .Send
End With

Set objMessage = Nothing
Set objConfig = Nothing
Set objFields = Nothing
End Sub