Private Sub Form_Open(Cancel As Integer)
DoCmd.RunCommand acCmdSizeToFitForm
DoCmd.Close acForm, "frmPlateCheck"
DoCmd.Close acForm, "frmMainMenu"
DoCmd.Close acForm, "frmMasterName"
DoCmd.Close acForm, "frmMaxSearch"
DoCmd.Close acForm, "frmAssociatedVehicleToPerson"
DoCmd.Close acForm, "frmVehicleRelatedToGang"
DoCmd.Close acForm, "frmVehicleRelatedToLocation"
DoCmd.Close acForm, "frmGangs"
DoCmd.Close acForm, "frmSwitchBoard"
End Sub

Dim intX As Integer
   Dim intCount As Integer
   intCount = Forms.Count - 1
   For intX = intCount To 0 Step -1
        If Forms(intX).Name <> "NameOfFormNotToClose" Then
            DoCmd.Close acForm, Forms(intX).Name
        End If
   Next

I guess the question has to be why so many forms open in the first place,

Public Sub CloseLeftOverForms(strFormsToRemain)

' Usage: call the Sub with argument being a semicolon-separated list of

'   Form Names to remain open.

' Example:

'   Call CloseLeftOverForms("frmMenu_Main;frmLogIn")

'   to close all Forms except frmLogIn & frmMenu_Main

  

  Dim intCountFormsToRemain As Integer

  Dim intCount As Integer

  Dim intIndex As Integer

  Dim frm As Access.Form

  

On Error GoTo CloseLeftOverForms_Err

  intCountFormsToRemain = UBound(Split(strFormsToRemain, ";")) + 1

  intCount = Forms.Count

  If (intCount > intCountFormsToRemain) Then

    For intIndex = intCount - 1 To 0 Step -1

      If (InStr(1, strFormsToRemain, Forms.Item(intIndex).Name) = 0) Then

        DoCmd.Close acForm, Forms.Item(intIndex).Name, acSaveNo

      End If

    Next intIndex

  End If

  

CloseLeftOverForms_Exit:

  On Error Resume Next

  Exit Sub

  

CloseLeftOverForms_Err:

  Select Case Err.Number

    Case 0

    Case Else

      MsgBox "Error " & Err.Number & ": " & Err.Description & vbCrLf & vbCrLf & _

        "(Programmer's note: Sub CloseLeftOverForms)", _

        vbOKOnly + vbCritical, "Run-time Error!"

  End Select

  Resume CloseLeftOverForms_Exit

End Sub

' from UtterAccess - written by VanThienDinh
'
' I modified slightly to prevent a problem with the InStr() finding a match
' on partial form name, for example, if you have frmInventory and frmInventorySearch
' and pass in "frmInventory" then both would remain open
'
' Usage: call the Sub with argument being a semicolon-separated list of
'   Form Names to remain open.
' Example:
'   Call CloseLeftOverForms("frmMenu_Main;frmLogIn")
'   to close all Forms except frmLogIn & frmMenu_Main
'
Public Sub CloseLeftOverForms(strFormsToRemain As String)
    On Error GoTo CloseLeftOverForms_Err
    
    Dim nCountFormsToRemain As Long
    Dim nCount As Long
    Dim nIndex As Long
    Dim frm As Access.Form
    Dim arrFormsToRemain() As String
    Dim bClose As Boolean, x As Long
    
    arrFormsToRemain = Split(strFormsToRemain, ";")
    nCountFormsToRemain = UBound(arrFormsToRemain) + 1
    nCount = Forms.Count
    
    If (nCount > nCountFormsToRemain) Then
        For nIndex = (nCount - 1) To 0 Step -1
            bClose = True
            For x = 0 To (nCountFormsToRemain - 1)
                If (StrComp(arrFormsToRemain(x), Forms.Item(nIndex).name, vbTextCompare) = 0) Then
                    ' have a match, leave this form open
                    bClose = False
                    Exit For
                End If
            Next x
            
            If bClose = True Then
                DoCmd.Close acForm, Forms.Item(nIndex).name, acSaveNo
            End If
        Next nIndex
    End If
    
CloseLeftOverForms_Exit:
    On Error Resume Next
    Exit Sub
    
CloseLeftOverForms_Err:
    Select Case Err.Number
      Case 0
      Case Else
        MsgBox "Error " & Err.Number & ": " & Err.Description & vbCrLf & vbCrLf & _
          "(from Sub CloseLeftOverForms)", _
          vbOKOnly Or vbCritical, "Run-time Error!"
    End Select
    Resume CloseLeftOverForms_Exit
End Sub