Public Function fGetNewNum() As Long
    On Error GoTo Error_Handler
    Dim rstID As dao.Recordset
    Dim lngID As Long
    Dim intRetry As Integer
    Dim db As dao.Database
    Set db = CurrentDb
    Set rstID = db.OpenRecordset("tblNextSeries")
    If rstID.EOF And rstID.BOF Then
        ' No records yet, start with one
        lngID = 1
        With rstID
            .AddNew
            !fNextSeries = lngID
            .Update
        End With
    Else
        ' Edit the existing record
        rstID.MoveFirst
        lngID = rstID!NEXT_MRR_NO + 1
        With rstID
            .Edit
            !fNextSeries = lngID
            .Update
        End With
    End If
    fGetNewNum = lngID
Exit_Here:
    On Error Resume Next
    rstID.Close
    Set rstID = Nothing
    Set db = Nothing
    Exit Function
Error_Handler:        'If someone is editing this record trap the error
    If Err = 3188 Then
        intRetry = intRetry + 1
        If intRetry < 100 Then
            Resume
        Else    'Time out retries
            MsgBox "Another user editing this number", vbOKOnly, "Please Wait"
            Resume Exit_Here
        End If
    Else    'Handle other errors
        MsgBox Err.Number & ": " & Err.Description, 48, "Problem Generating Number"
        Resume Exit_Here
    End If
End Function