Function DayNames_Between_Dates(inDate1 As Date, _
                                inDate2 As Date, _
                                strReqdDay As Variant) _
                           As Long
                                      
    ' Return the number of times a SPECIFIC "Day of Week" occurs between the dates input
    ' i.e. How many Mondays, or Tuesdays, etc etc ....based on the 3rd parameter passed
    '
    ' Inputs:   inDate1     First Date
    '           inDate2     Second Date (in Range)
    '           strReqdDay  any ONE of:     1 or  "Sun", "Sunday", _
    '                                       2 or  "Mon", "Monday", _
    '                                       3 or  "Tue", "Tues", "Tuesday", _
    '                                       4 or  "Wed", "Wednesday", _
    '                                       5 or  "Thu", "Thur", "Thurs", "Thursday", _
    '                                       6 or  "Fri", "Friday", _
    '                                       7 or  "Sat", "Saturday"
                                          
    Dim DaysCount As Integer
    Dim DayAdjuster As Integer
    Dim dteIn1 As Date
    Dim dteIn2 As Date
    
    ' Set input dates in correct date sequence
    
    If inDate1 <= inDate2 Then
        dteIn1 = inDate1
        dteIn2 = inDate2
    Else
        dteIn1 = inDate2
        dteIn2 = inDate1
    End If
        
    If Not IsNumeric(strReqdDay) Then
        ' If parameter passed is 'Text', then convert it into the equivalent numeric for use later
        Select Case strReqdDay
            Case "Sun", "Sunday"
                strReqdDay = 1
            Case "Mon", "Monday"
                strReqdDay = 2
            Case "Tue", "Tues", "Tuesday"
                strReqdDay = 3
            Case "Wed", "Wednesday"
                strReqdDay = 4
            Case "Thu", "Thur", "Thurs", "Thursday"
                strReqdDay = 5
            Case "Fri", "Friday"
                strReqdDay = 6
            Case "Sat", "Saturday"
                strReqdDay = 7
         End Select
    End If
    
    DayAdjuster = 1
        
    Do Until dteIn1 > dteIn2
        
        If DatePart("w", dteIn1, vbSunday) = strReqdDay Then       ' Only work with REQUIRED day
            DaysCount = DaysCount + 1
            ' Once the first reqd 'Day' is found, the function can
            ' THEN jump forward a week at a time (quicker processing)
            DayAdjuster = 7
        End If
        
        dteIn1 = DateAdd("d", DayAdjuster, dteIn1)
    Loop
  
   DayNames_Between_Dates = DaysCount
  
End Function