Private Sub fx()
Dim rst        As DAO.Recordset
Dim db         As DAO.Database
Dim strSQL     As String

    Set db = CurrentDb
    strSQL = "SELECT DISTINCT RecID,UserID FROM tblEmployeeData"
    Set rst = db.OpenRecordset(strSQL, dbOpenSnapshot)

    With rst
        Do Until .EOF
            strSQL = "(SELECT UserID,UserResume FROM tblEmployeeData WHERE RecID = " & !RecID & ")"
            ExportToCSV_A strSQL, "C:\temp\" & !UserID & ".txt", , False
            .MoveNext
        Loop
    End With

    Set rst = Nothing
End Sub

--------------------------------------------------
Private Sub Command1_Click()
    Call fx
End Sub
-------------------------------------------------

Public Function ExportToCSV_A(strSource As String, _
                              strFilename As String, _
                              Optional strColumnDelimiter As String = ",", _
                              Optional blHeaders As Boolean = False) As Byte
'Exports a table or query or SQL statement to a text file.  If a SQL is passed
'as the source, enclose it in Parenthesis.

Dim intChannel As Integer
Dim strSQL     As String
Dim strHeaders As String
Dim x          As Integer

    'Close any open files
    For intChannel = 1 To 511
        Close #intChannel
    Next intChannel

    'Open a channel to communicate with your TEMP file and
    intChannel = FreeFile
    Open strFilename For Output Access Write As #intChannel

    'Write the contents of the table to the file
    'Open the source
    strSQL = "SELECT * FROM " & strSource & " As vTbl"

    With CurrentProject.Connection.Execute(strSQL, , 1)    'adCmdText = 1

    'Build Headers if appropriate
        If blHeaders = True Then
            For x = 0 To .Fields.Count - 1
                strHeaders = strHeaders & strColumnDelimiter & .Fields(x).Name
            Next
            strHeaders = Mid(strHeaders, Len(strColumnDelimiter) + 1) & vbCrLf
        End If

    'Write to the CSV file
        Print #intChannel, strHeaders & .GetString(2, , strColumnDelimiter, vbCrLf, "<NULL>")    'adClipString = 2

    End With

    'Close all the files
    Close #intChannel

End Function