Private Sub TreeViewMenu_NodeClick(ByVal Node As Object) ' This is a treeview control with exposes a "NodeClick" event
Dim dbs As Database
Dim intNodeIndex As Integer
Dim strNodeCommand As String
Dim testnode As Variant
Dim appC As New Appconstants

On Error GoTo errHandler
Call FormCaption(frm:=Me, sCap:=Node.Text) ' each node in the control has a .text property. Call the procedure "FormCaption" to swap out the form's caption for each selection in the treeview
intNodeIndex = Node.Index ' each node has a .Index property
testnode = Node.Key 'each node has a .Key property

strNodeCommand = DLookup("Argument", "tblTreemenu", "tblTreemenu.key = '" & testnode & "'") ' retrieve the name of the argument from a lookup table. it'll be either a form name or one of two other actions

Select Case strNodeCommand

Case "Exit" ' if the user clicks the node labelled "exit", we bail out and go home for the day
    Me.sfrmDisplay.SourceObject = "frmBlank"
    Set dbs = CurrentDb
    dbs.Properties!AppTitle = appC.AppName
    Me.Application.RefreshTitleBar
    Application.Quit
Case "Calculator" ' if the user wants to open the pop-up calculator, it's different from loading a subform
    DoCmd.OpenForm "frmCalculator", acNormal
  
Case Else ' otherwise, load the form into the subform control and reexpand all of the nodes in the tree view
    Me.sfrmDisplay.SourceObject = strNodeCommand
    ActiveXCtl4.Nodes(intNodeIndex).Expanded = True
End Select

Cleanup:
    On Error Resume Next
exitProc:
  Exit Sub
errHandler:
    If Err <> AppErr.FormNotFound Then
        Call GlobalErrorMessage(iNum:=Err, iLn:=Erl, sFrm:=Screen.ActiveForm.Caption, sCtl:="Main Menu Control") 'this is MY custom error handler, not provided here
    End If
    Resume Cleanup
    Resume
  End Sub